#include <amxmodx>
#include <amxmisc>
#include <fakemeta>
#include <cstrike>

#define PLUGIN "Virus SmokeNade"
#define VERSION "1.0"
#define AUTHOR "anakin_cstrike"

#define fm_find_ent_in_sphere(%1,%2,%3) engfunc(EngFunc_FindEntityInSphere, %1, %2, %3)

// radius for virus
#define radius    200.0

/********************************* Global Variables *********************************/

new
toggle_plugin,toggle_damage,toggle_interval,toggle_intdamage,
toggle_glowduration,toggle_antidot,toggle_antidotcost,
toggle_glow,toggle_announce,toggle_antidotdur,toggle_antidotknife,
toggle_trail,toggle_speed,toggle_touch,toggle_antidotzone;

new p_toggle,p_damage,p_int,p_dmg,p_announce,p_speed,p_glowdur,p_anticost,p_antidur;
new g_msgscreenfade,g_msgstatusicon,g_msgbartime,g_msgsaytext,g_msgscoreinfo,g_msgdeathmsg;
new g_Timer;

new g_trail,g_explode,g_smoke;

new bool:g_Virused[33],bool:g_Antidot[33];
new g_Count[33];

/********************************* Initialization *********************************/
public plugin_init()
{
   register_plugin(PLUGIN, VERSION, AUTHOR);
     
   /* Fakemeta Forwards */
   register_forward(FM_Touch,"fw_touch");
   register_forward(FM_SetModel,"fw_setmodel",1);
   register_forward(FM_EmitSound,"fw_emitsound");
   register_forward(FM_PlayerPreThink,"fw_prethink");
     
   /* Events */
   register_event("CurWeapon", "hook_curwpn", "be", "1=1", "2!29");
   register_event("HLTV","hook_newround","a","1=0","2=0");
   register_event("ResetHUD","hook_reset","b");
   register_clcmd("say_team /antidote","antidote_cmd");
   register_clcmd("say /antidote","antidote_cmd");
     
   /* Cvars, a lot ^^ */
   toggle_plugin = register_cvar("virusnade_plugin","1");
   toggle_damage = register_cvar("virusnade_impactdamage","10");
   toggle_interval = register_cvar("virusnade_damageinterval","3");
   toggle_intdamage = register_cvar("virusnade_intervaldamage","5");
   toggle_glow = register_cvar("virusnade_glow","1");
   toggle_glowduration = register_cvar("virusnade_glowduration","2");
   toggle_trail = register_cvar("virusnade_trail","1");
   toggle_touch = register_cvar("virusnade_touch","1");
   toggle_speed = register_cvar("virusnade_changespeed","1");
   toggle_announce = register_cvar("virusnade_announce","1");
   toggle_antidot = register_cvar("virusnade_antidote","1");
   toggle_antidotcost = register_cvar("virusnade_antidotecost","1500");
   toggle_antidotdur = register_cvar("virusnade_antidoteduration","10");
   toggle_antidotknife = register_cvar("virusnade_antidoteonlyknife","1");
   toggle_antidotzone = register_cvar("virusnade_antidotebuyzone","1");
     
   /* Messages */
   g_msgscreenfade = get_user_msgid("ScreenFade");
   g_msgstatusicon = get_user_msgid("StatusIcon");
   g_msgscoreinfo = get_user_msgid("ScoreInfo");
   g_msgsaytext = get_user_msgid("SayText");
   g_msgbartime = get_user_msgid("BarTime");
   g_msgdeathmsg = get_user_msgid("DeathMsg");
}

/********************************* Precache *********************************/
public plugin_precache()
{
   g_trail = precache_model("sprites/laserbeam.spr");
   g_explode = precache_model("sprites/shockwave.spr");
   g_smoke = precache_model("sprites/steam1.spr");
}

/********************************* Getting Cvar Values *********************************/
public hook_newround()
{
   p_toggle = get_pcvar_num(toggle_plugin);
   p_damage = get_pcvar_num(toggle_damage);
   p_dmg = get_pcvar_num(toggle_intdamage);
   p_int = get_pcvar_num(toggle_interval);
   p_announce = get_pcvar_num(toggle_announce);
   p_speed = get_pcvar_num(toggle_speed);
   p_glowdur = get_pcvar_num(toggle_glowduration);
   p_anticost = get_pcvar_num(toggle_antidotcost);
   p_antidur = get_pcvar_num(toggle_antidotdur);
     
   g_Timer = p_antidur;
}
     
/********************************* Antidote *********************************/   
public antidote_cmd(id)
{
   // make shure the plugin is enabled
   if(p_toggle != 1)
    return PLUGIN_HANDLED;
     
   // check if buying antidote option is enabled
   if(get_pcvar_num(toggle_antidot) != 1)
   {
    print(id,"You're not allowed to buy an antidote!");
    return PLUGIN_HANDLED;
   }
     
   // make shure the player is alive
   if(!is_user_alive(id))
   {
    print(id,"You must be alive to buy an antidote!");
    return PLUGIN_HANDLED;
   }
     
   // check if is in buyzone
   if(!cs_get_user_buyzone(id) && get_pcvar_num(toggle_antidotzone) == 1)
   {
    print(id,"You must be in Buyzone to buy an antidote!");
    return PLUGIN_CONTINUE;
   }
     
   // make shure he has enough money
   new money = cs_get_user_money(id);
   if(money < p_anticost)
   {
    print(id,"Not enough money, you need $%d to buy an antidote!",p_anticost);
    center(id,"#Cstrike_TitlesTXT_Not_Enough_Money");
    return PLUGIN_CONTINUE;
   }
     
   // check if is infected
   if(!g_Virused[id])
   {
    print(id,"You're not infected with the virus!");
    return PLUGIN_CONTINUE;
   }
     
   // check if he allready bought an antidote
   if(g_Antidot[id])
   {
    print(id,"You've already bought the antidote!");
    center(id,"#Cstrike_TitlesTXT_Cannot_Carry_Anymore");
    return PLUGIN_HANDLED;
   }
     
   g_Timer = p_antidur;
   g_Antidot[id] = true;
     
   // remove flashing icon, set a normal   
   Icon(id,1,"dmg_gas",0,255,0);
   set_task(1.0,"countdown",id+12345,_,_,"b");
   cs_set_user_money(id,money - 1500,1); // remove money
     
   // create a bar
   message_begin(MSG_ONE,g_msgbartime,_,id);
   write_short(p_antidur);
   message_end();
     
   print(id,"You've bought an antidote for $%d !",p_anticost);
     
   return PLUGIN_CONTINUE;
}

/********************************* Spreading Virus >:) *********************************/
     
public fw_emitsound(Ent,Channel,const Sound[],Float:Volume,Float:Attenuation,Flags,Pitch)   
{
   // make shure the plugin is enabled
   if(p_toggle != 1)
    return FMRES_IGNORED;
   // make shure was a smokenade   
   if(!equali(Sound,"weapons/sg_explode.wav"))
    return FMRES_IGNORED;
      
   new Float:origin[3],i,name[32];
   pev(Ent, pev_origin, origin);
   new owner = pev(Ent,pev_owner);
     
   Light(origin); // makes a nice light effect
   Render(Ent,kRenderFxNone,255,255,255,15); //set the glow back to normal
     
   while((i = fm_find_ent_in_sphere(i,origin,radius)) != 0)
   {
    if(!is_user_alive(i))
     continue;
    // check if is allready infected   
    if(g_Virused[i])
     continue;
       
    new Float:iorigin[3];   
    pev(i,pev_origin,iorigin);   
    g_Virused[i] = true;   
      
    new hp = get_user_health(i);
    // check if hp is less or equal to nade damage
    if(hp <= p_damage)
    {
     Kill(owner,i); // kill the player
       
     // explode effects
     Smoke(iorigin);
     Cylinder(iorigin);
       
     // lets make a nice screenfade
     Fade(i,(6<<10),(5<<10),(1<<12),0,255,0,175);
       
     continue;
    } else {
       
     new total = hp - p_damage;
     if(total <= 0)   
      user_kill(i);
     else   
      set_pev(i,pev_health,float(total)); //inflict damage
        
     Fade(i,(1<<10),(1<<10),(1<<12),0,255,0,75);
       
     if(get_pcvar_num(toggle_glow) == 1)
     {
      // glow player
      Render(i,kRenderFxGlowShell,0,255,0,kRenderNormal,20);
      set_task(float(p_glowdur),"glow_normal",i);
        
      // set an icon on the left of the player's screen
      Icon(i,2,"dmg_gas",0,255,0);
     }
     set_task(float(p_int),"virus",i+123,_,_,"b");
       
     if(p_announce == 1)
     {
      // anounce infection
      get_user_name(i,name,31);
      set_hudmessage(0, 200, 0, 0.05, 0.25, 0, 6.0, 3.0)
      show_hudmessage(0, "%s has been infected with the virus!",name);
     }
    }
   }
     
   return FMRES_IGNORED;
}

/********************************* SetModel Forward *********************************/   

public fw_setmodel(ent,model[])
{
   // make shure the plugin is enabled
   if(p_toggle != 1)
    return FMRES_IGNORED;
   // make shure was is a smokenade    
   if(!equali(model,"models/w_smokegrenade.mdl"))
    return FMRES_IGNORED;
   // glow nade
   Render(ent,kRenderFxGlowShell,0,255,0,kRenderNormal,15);
   if(get_pcvar_num(toggle_trail) == 1)
    Follow(ent,g_trail,10,5,0,255,0,175); // set the trail
     
   return FMRES_IGNORED;
}

/********************************* PreThink *********************************/   

public fw_prethink(id)
{
   // make shure the plugin is enabled
   if(p_toggle != 1)
    return FMRES_IGNORED;
   // must be alive   
   if(!is_user_alive(id))
    return FMRES_IGNORED;
   // check if is infected   
   if(!g_Virused[id])
    return FMRES_IGNORED;
   // stop if the changing speed cvar is disabled   
   if(p_speed != 1)
    return FMRES_IGNORED;
      
   if(g_Count[id] >= 5) Speed(id,200.0);
   else if(g_Count[id] >= 10) Speed(id,150.0);
   else if(g_Count[id] >= 15) Speed(id,100.0);
     
   return FMRES_IGNORED;
}

/********************************* Touch Stuff *********************************/
     
public fw_touch(touched, toucher)
{
   // make shure the plugin is enabled
   if(p_toggle != 1)
    return FMRES_IGNORED;
   // make shure the touch option is enabled   
   if(get_pcvar_num(toggle_touch) != 1)
    return FMRES_IGNORED;
     
   static dclass[32],rclass[32],dname[32],rname[32];
     
   // get class and name
   pev(touched, pev_classname, dclass, sizeof dclass - 1);
   pev(toucher, pev_classname, rclass, sizeof rclass - 1);
   get_user_name(touched,dname,sizeof dname - 1);
   get_user_name(toucher,rname,sizeof rname - 1);
     
   if(equali(dclass,"player") && equali(rclass,"player"))
   {
    if(g_Virused[toucher])
    {
     if(!g_Virused[touched])
     {
      g_Virused[touched] = true;
        
      // create a screenfade
      Fade(toucher,(1<<10),(1<<10),(1<<12),0,255,0,75);
      Icon(toucher,2,"dmg_gas",0,255,0);
        
      // glow player
      if(get_pcvar_num(toggle_glow) == 1)
      {
       Render(touched,kRenderFxGlowShell,0,255,0,kRenderNormal,20);
       set_task(float(p_glowdur),"glow_normal",touched);
      }
      set_task(float(p_int),"virus",touched+123,_,_,"b");
        
      // anounce infection
      if(p_announce == 1)
      {
       set_hudmessage(0, 200, 0, 0.05, 0.25, 0, 6.0, 3.0);
       show_hudmessage(0, "%s has take the virus^n from %s",dname,rname);
      }
     }
    }
   }
     
   return FMRES_IGNORED;
}

/********************************* Curent Weapon stuff *********************************/   
public hook_curwpn(id)
{
   // make shure the plugin is enabled
   if(p_toggle != 1)
    return PLUGIN_CONTINUE;   
   if(!is_user_alive(id))
    return PLUGIN_CONTINUE;
      
   // allow player to play only with the knife   
   if(g_Antidot[id] && get_pcvar_num(toggle_antidotknife) == 1)
    engclient_cmd(id,"weapon_knife");
     
   return PLUGIN_CONTINUE;
}

/********************************* Antidote task *********************************/   
public countdown(task)
{
     
   new id = task - 12345;
     
   set_hudmessage(0, 255, 0, 0.02, 0.20, 0, 6.0, 2.0);
   show_hudmessage(id, "Taking antidote: %d",g_Timer);
   g_Timer--;
     
   if(g_Timer <= 0)
   {
    // remove decreasing task
    if(task_exists(id+12345))
     remove_task(id+12345);
      
    g_Antidot[id] = false;
    g_Virused[id] = false;
      
    Icon(id,0,"dmg_gas",0,0,0);
    Speed(id,280.0); // set speed back to normal
    remove_task(id+123);
      
    set_hudmessage(0, 255, 0, 0.02, 0.20, 0, 6.0, 3.0);
    show_hudmessage(id, "Antidote taken!");
      
    return;
   }
}

// normal glow */
public glow_normal(id) Render(id,kRenderFxNone,0,0,0,kRenderNormal,255);

/********************************* Virus Descreasing Effect *********************************/   
public virus(task)
{
   new index = task-123;
   g_Count[index]++;
     
   // get player's health
   new hp = get_user_health(index);
   new total = hp - p_dmg;
     
   // get player's name
   new name[32];
   get_user_name(index,name,31);
     
   if(total <= 0)
   {
    user_kill(index);
    Icon(index,0,"dmg_gas",0,0,0);
      
    Speed(index,280.0);
    g_Count[index] = 0;
      
    // anounce player death
    if(p_announce == 1)
    {
     set_hudmessage(0, 200, 0, 0.05, 0.25, 0, 6.0, 3.0);
     show_hudmessage(0, "%s was truck down by the virus!",name);
    }
   } else
    is_user_alive(index) ? set_pev(index,pev_health,float(total)) : remove_task(index); //remove hp
     
   Fade(index,(1<<10),(1<<10),(1<<12),0,255,0,35);
     
   // change speed
   if(p_speed == 1)
   {
    if(g_Count[index] >= 5) Speed(index,200.0);
    else if(g_Count[index] >= 10) Speed(index,150.0);
    else if(g_Count[index] >= 15) Speed(index,100.0);
   }
}

/********************************* Reset Hud *********************************/   
public hook_reset(id)
{
   g_Virused[id] = false;
   Icon(id,0,"dmg_gas",0,0,0);
     
   if(task_exists(id+123))
   {
    remove_task(id+123);
      
    Speed(id,280.0);
    g_Count[id] = 0;
   }
}

/********************************* Effects *********************************/   
public Light(Float:forigin[3])
{
   message_begin(MSG_BROADCAST,SVC_TEMPENTITY);
   write_byte(TE_DLIGHT);
   write_coord(floatround(forigin[0]));   
   write_coord(floatround(forigin[1]));   
   write_coord(floatround(forigin[2]));   
   write_byte(60);
   write_byte(0);
   write_byte(185);
   write_byte(0);
   write_byte(8);
   write_byte(60);
   message_end();
}

/* Smoke Effect */
public Smoke(Float:forigin[3])
{
   message_begin(MSG_BROADCAST,SVC_TEMPENTITY);
   write_byte(TE_SMOKE);
   write_coord(floatround(forigin[0]));
   write_coord(floatround(forigin[1]));
   write_coord(floatround(forigin[2]));
   write_short(g_smoke);
   write_byte(random_num(30,40));
   write_byte(5);
   message_end();
}
/* Explode stuff */
public Cylinder(Float:forigin[3])
{
   new origin[3];
   FVecIVec(forigin,origin);   
   CreateCylinder(origin,550,g_explode,0,0,6,60,0,0,210,0,175,0);
   CreateCylinder(origin,700,g_explode,0,0,6,60,0,0,235,0,150,0);
   CreateCylinder(origin,850,g_explode,0,0,6,60,0,15,255,15,100,0);
}

/********************************* Usefull stocks  *********************************/   
/*********************************                 *********************************/

/* Usefull and less code xD */
CreateCylinder(origin[3],addrad,sprite,startfrate,framerate,life,width,amplitude,red,green,blue,brightness,speed)
{
   message_begin(MSG_BROADCAST,SVC_TEMPENTITY);
   write_byte(TE_BEAMCYLINDER);
   write_coord(origin[0]);
   write_coord(origin[1]);
   write_coord(origin[2]);
   write_coord(origin[0]);
   write_coord(origin[1]);
   write_coord(origin[2] + addrad);
   write_short(sprite);
   write_byte(startfrate);
   write_byte(framerate);
   write_byte(life);
   write_byte(width);
   write_byte(amplitude);
   write_byte(red);
   write_byte(green);
   write_byte(blue);
   write_byte(brightness);
   write_byte(speed);
   message_end();
}

/* Kill player, update score, money */
Kill(killer,victim)
{
   user_silentkill(victim);
     
   new kteam = get_user_team(killer);
   new vteam = get_user_team(victim);
   new kmoney = cs_get_user_money(killer);
   new kfrags;
     
   // remove money if teamkill
   if(kteam == vteam)
   {
    kfrags = get_user_frags(killer) - 1;
    cs_set_user_money(killer,kmoney - 300,1);
   } else {
    kfrags = get_user_frags(killer) + 1;
    cs_set_user_money(killer,kmoney + 300,1); // otherwise give kill bonus
   }
     
   new vfrags = get_user_frags(victim);
   new kdeaths = get_user_deaths(killer);
   new vdeaths = get_user_deaths(victim);
     
   // update score
   message_begin(MSG_ALL,g_msgscoreinfo);
   write_byte(killer);
   write_short(kfrags);
   write_short(kdeaths);
   write_short(0);
   write_short(kteam);
   message_end();
     
   message_begin(MSG_ALL,g_msgscoreinfo);
   write_byte(victim);
   write_short(vfrags+1);
   write_short(vdeaths);
   write_short(0);
   write_short(vteam);
   message_end();
     
   // set a death message
   message_begin(MSG_ALL,g_msgdeathmsg,{0,0,0},0);
   write_byte(killer);
   write_byte(victim);
   write_byte(0);
   write_string("virusnade");
   message_end();
     
   Log(killer,victim,"virusnade");
}

/* Log Kill */
Log(killer,victim,weapond[])
{
   new Buffer[256];
   new kname[32],vname[32];
   new kteam[16],vteam[16];
   new kauth[32],vauth[32];
   new kid,vid;
     
   // killer info
   get_user_name(killer,kname,31);
   get_user_team(killer,kteam,15);
   get_user_authid(killer,kauth,31);
   kid = get_user_userid(killer);
     
   // victim info
   get_user_name(victim,vname,31);
   get_user_team(victim,vteam,15);
   get_user_authid(victim,vauth,31);
   vid = get_user_userid(victim);
     
   // teamkill message
   if(killer == victim)
    format(Buffer,255,"^"%s<%d><%s><%s>^" committed suicide with ^"%s^"",vname,vid,vteam,vauth,weapond);
   else
    format(Buffer,255,"^"%s<%d><%s><%s>^" killed ^"%s<%d><%s><%s>^" with ^"%s^"",kname,kid,kteam,kauth,vname,vid,vteam,vauth,weapond);
     
   log_message("%s",Buffer);
}

/* Fakemeta Rendering */
Render(index, fx=kRenderFxNone, r=255, g=255, b=255,render=kRenderNormal,amount=16)
{
   set_pev(index, pev_renderfx, fx);
   new Float:RenderColor[3];
   RenderColor[0] = float(r);    
   RenderColor[1] = float(g);    
   RenderColor[2] = float(b);   
   set_pev(index, pev_rendercolor, RenderColor);
   set_pev(index, pev_rendermode, render);    
   set_pev(index, pev_renderamt, float(amount));
   return 1;   
}

/* Set a BeamFollow */
Follow(entity,index,life,width,red,green,blue,alpha)
{
   message_begin(MSG_BROADCAST, SVC_TEMPENTITY);
   write_byte(TE_BEAMFOLLOW);
   write_short(entity);
   write_short(index);
   write_byte(life);
   write_byte(width);
   write_byte(red);
   write_byte(green);
   write_byte(blue);
   write_byte(alpha);
   message_end();
}

/* An usefull and advanced print stock */
print(index,const message[],{Float,Sql,Result,_}:...)
{
   new Buffer[128],Buffer2[128];
   formatex(Buffer2,sizeof Buffer2 - 1,"%s",message);
   vformat(Buffer, sizeof Buffer - 1, Buffer2, 3);
     
   if(!is_user_connected(index)) return 0;
     
   message_begin(MSG_ONE,g_msgsaytext,_,index);
   write_byte(index);
   write_string(Buffer);
   message_end();
     
   return 1;
}

/* ScreenFade */
Fade(index,duration,holdtime,flags,red,green,blue,alpha)
{
   message_begin(MSG_ONE,g_msgscreenfade,{0,0,0},index);
   write_short(duration);
   write_short(holdtime);
   write_short(flags);
   write_byte(red);
   write_byte(green);
   write_byte(blue);
   write_byte(alpha);
   message_end();
}

/* Manage Statuc Icon */
Icon(index,mode=2,const sprite[],red=0,green=255,blue=0)
{
   message_begin(MSG_ONE,g_msgstatusicon,{0,0,0},index);
   write_byte(mode);
   write_string(sprite);   
   write_byte(red);
   write_byte(green);   
   write_byte(blue);   
   message_end();
}

/* Center message */
center(index,const message[])
{
   if(!is_user_connected(index)) return 0;
   client_print(index,print_center,"%s",message);
   return 1;
}

/* Set maxspeed */
Speed(index,Float:speed) set_pev(index,pev_maxspeed,speed);