#include <amxmodx>
#include <amxmisc>
#include <hamsandwich>
#include <fakemeta>

#define PLUGIN "Advanced ReSpawn Addon"
#define VERSION "1.0"
#define AUTHOR "Sh0oT3R"

new hudSyncCountdown
new cvar_respawn, cvar_resp_time, cvar_sp, cvar_sptime, cvar_countdown, cvar_sp_cd, cvar_respawn_rand;
new respawn_timeleft[33], sp_timeleft[33]
public plugin_init()  
{
    register_plugin(PLUGIN, VERSION, AUTHOR)
    register_clcmd("say /respawn", "respawn") // Type this to respawn yourself
    cvar_sp = register_cvar("arsa_sp", "1") // Enable/Disable Spawn Protection
    cvar_sptime = register_cvar("arsa_sptime", "3") // Timer for Spawn Protection
    cvar_sp_cd = register_cvar("arsa_sp_countdown", "0") // Spawn Protection countdown type. 0 - Disable, 1 - Client Print, 2 - Hud Message.
    cvar_respawn = register_cvar("arsa_respawn","1") // Enable/Disable Respawn
    cvar_resp_time = register_cvar("arsa_respawn_time", "3.0") // Timer for Respawn
    cvar_respawn_rand = register_cvar("arsa_respawn_randomized", "0") // Enable/Disable random team spawn
    cvar_countdown = register_cvar("arsa_respawn_countdown", "0") // Respawn coundown type. 0 - Disable, 1 - Client Print, 2 - Hud Message.
    RegisterHam(Ham_Killed, "player", "fw_PlayerKilled")
    RegisterHam(Ham_Spawn, "player", "fw_PlayerSpawn_Post", 1)
     
    hudSyncCountdown = CreateHudSyncObj();
}
public client_disconnect(id)
{
    remove_task(id)
     
}
public fw_PlayerKilled(victim, attacker, shouldgib)
{
    if(get_pcvar_num(cvar_respawn))
    {
       new Float:g_Resp_Time = get_pcvar_float(cvar_resp_time)
       respawn_timeleft [victim]= floatround(g_Resp_Time)
       respawn_countdown(victim);
       set_task(g_Resp_Time, "respawn",victim)
    }
    return PLUGIN_HANDLED
}
public respawn_countdown(id)
{
    if(!is_user_connected(id) || is_user_alive(id) || !get_pcvar_num(cvar_countdown))
    {
       respawn_timeleft [id]= 0;
       return;
    }
     
    if(get_pcvar_num(cvar_countdown) == 1)
    {
       if(respawn_timeleft [id]== 1)
          client_print(id,print_center,"You will respawn in %i second", respawn_timeleft[id]);
        
       else
          client_print(id,print_center,"You will respawn in %i seconds", respawn_timeleft[id]);
    }
     
    if(get_pcvar_num(cvar_countdown) == 2)
    {
       if(respawn_timeleft [id]== 1)
       {
          set_hudmessage(255,255,255,-1.0,0.75,0,6.0,1.0,0.1,0.5);
          ShowSyncHudMsg(id,hudSyncCountdown,"You will respawn in %i second",respawn_timeleft[id]);
       }
       else
       {
          set_hudmessage(255,255,255,-1.0,0.75,0,6.0,1.0,0.1,0.5);
          ShowSyncHudMsg(id,hudSyncCountdown,"You will respawn in %i seconds",respawn_timeleft[id]);
       }
    }

    if(--respawn_timeleft [id]>= 1) set_task(1.0,"respawn_countdown",id);
}
public respawn(id)
{
    new random_team = random_num(1,2)    
     
    if(get_pcvar_num(cvar_respawn_rand))
       fm_cs_set_user_team(id, random_team)
     
    if(get_pcvar_num(cvar_respawn) && !is_user_alive(id))
       ExecuteHamB(Ham_CS_RoundRespawn, id)
     
        

}

public fw_PlayerSpawn_Post(id)
{
    if(get_pcvar_num(cvar_sp) && (is_user_alive(id) || is_user_bot(id)))
    {
       set_task(0.1, "sp_on", id)
    }
        
}
public sp_on(id)
{
    new Float:g_SpTime = get_pcvar_float(cvar_sptime)
    sp_timeleft [id]= floatround(g_SpTime)

    set_pev(id, pev_takedamage, 0.0)

    if(get_user_team(id) == 1)
    {
       fm_set_rendering(id, kRenderFxGlowShell, 255, 0, 0, kRenderNormal, 25)
    }

    if(get_user_team(id) == 2)
    {
       fm_set_rendering(id, kRenderFxGlowShell, 0, 0, 255, kRenderNormal, 25)
    }

    sp_countdown(id)
    set_task(g_SpTime, "sp_off", id)

    return PLUGIN_HANDLED
}
public sp_countdown(id)
{
    if(!get_pcvar_num(cvar_sp_cd))
    {
       return;
    }
    new r,g,b
    if(get_user_team(id) == 1)
    {
       r = 255
       g = 0
       b = 0
    }

    if(get_user_team(id) == 2)
    {
       r = 0
       g = 0
       b = 255
    }
    if(get_pcvar_num(cvar_sp_cd) == 1)
    {
       if(sp_timeleft [id]== 1)
          client_print(id,print_center,"Spawn Protection is enabled for %i second", sp_timeleft[id]);
        
       else
          client_print(id,print_center,"Spawn Protection is enabled for %i seconds", sp_timeleft[id]);
    }
     
    if(get_pcvar_num(cvar_sp_cd) == 2)
    {
       if(sp_timeleft [id]== 1)
       {
          set_hudmessage(r,g,b,-1.0,0.75,0,6.0,1.0,0.1,0.5);
          ShowSyncHudMsg(id,hudSyncCountdown,"Spawn Protection is enabled for %i second",sp_timeleft[id]);
       }
       else  
       {
          set_hudmessage(r,g,b,-1.0,0.75,0,6.0,1.0,0.1,0.5);
          ShowSyncHudMsg(id,hudSyncCountdown,"Spawn Protection is enabled for %i seconds",sp_timeleft[id]);
       }
    }

    if(--sp_timeleft [id]>= 1) set_task(1.0,"sp_countdown",id);
}
public sp_off(id)  
{
    if(!is_user_connected(id) )
    {
       return PLUGIN_HANDLED
    }
    else
    {
        
       set_pev(id, pev_takedamage, 1.0)
       fm_set_rendering(id)
        
       return PLUGIN_HANDLED
    }

    return PLUGIN_HANDLED
}

stock fm_set_rendering(entity, fx = kRenderFxNone, r = 255, g = 255, b = 255, render = kRenderNormal, amount = 16)
{
    static Float:color[3]
    color[0] = float(r)
    color[1] = float(g)
    color[2] = float(b)
     
    set_pev(entity, pev_renderfx, fx)
    set_pev(entity, pev_rendercolor, color)
    set_pev(entity, pev_rendermode, render)
    set_pev(entity, pev_renderamt, float(amount))
}  
stock fm_cs_set_user_team(id, team)
{
    set_pdata_int(id, 114, team, 5)
}
// Sorry but I have no time to optimize plugin
/* AMXX-Studio Notes - DO NOT MODIFY BELOW HERE
*{\\ rtf1\\ ansi\\ deff0{\\ fonttbl{\\ f0\\ fnil Tahoma;}}\n\\ viewkind4\\ uc1\\ pard\\ lang1049\\ f0\\ fs16 \n\\ par }
*/