#include <amxmodx>
#include <amxmisc>

#define PLUGIN "Warcraft Item Bot"
#define VERSION "1.1"
#define AUTHOR "DA"

#define MAX_PDATA 3
#define PDATA_ITEMSIDE 0
#define PDATA_ITEM1 1
#define PDATA_ITEM2 2

#define MAX_PAGE_ITEMS 9
#define MAX_SHOPMENU_ITEMS 18

new p_data[33][MAX_PDATA];

new const ShopmenuLong_Names[MAX_SHOPMENU_ITEMS][] = {
"Ankh of Reincarnation",
"Boots of Speed",
"Claws of Attack",
"Cloak of Shadows",
"Mask of Death",
"Necklace of Immunity",
"Orb of Frost",
"Periapt of Health",
"Tome of Experience",
"Scroll of Respawning",
"Mole Protectant",
"Helm of Excellence",
"Amulet of the Cat",
"Sock of the Feater",
"Flaming Gloves of Warmth",
"Ring of Regeneration +1",
"Chameleon",
"Mole"
}

public plugin_init() {
register_plugin ( PLUGIN, VERSION, AUTHOR );

// Register the menu's
register_menu ( "BotMenu", 1023, "_HandleBotMenu" );
register_menu ( "Shopmenu12", 1023, "_ITEM_HandleShopMenu" );

// Event's
register_logevent ( "on_FreezeTimeComplete", 2, "0=World triggered", "1=Round_Start" );

// Commands
register_clcmd ( "say", "HandleSay", -1 );
register_clcmd ( "say_team", "HandleSay", -1 );
}

// New round started, set up the items
public on_FreezeTimeComplete()
{
static players[32], numofplayers;
get_players( players, numofplayers );

// Loop through all player's and set up their items
for ( new i = 0; i < numofplayers; ++i )
{
// the player should have a team
if ( get_user_team( players[i] ) )
{
if ( p_data[players[i]][PDATA_ITEM1] > -1 )
{
ITEM_Buy( players[i], p_data[players[i]][PDATA_ITEM1] );
}

if ( p_data[players[i]][PDATA_ITEM2] > -1 )
{
ITEM_Buy( players[i], p_data[players[i]][PDATA_ITEM2] );
}
}
}

return;
}

// player went in, should something do
public client_putinserver( id )
{
// Reset the data from the old player
p_data[id][PDATA_ITEM1] = -1;
p_data[id][PDATA_ITEM2] = -1;

return PLUGIN_CONTINUE;
}

// Open the Bot menu
MENU_ItemBot( id )
{
// wth, the player isn't on the server
if ( !is_user_connected( id ) )
{
return;
}

static MenuText[512], KEYS;

// Add the header
copy( MenuText, charsmax( MenuText ), "\yWarcraft Item Bot: Main Menu^n^n" );

// Add every menupoint
add( MenuText, charsmax( MenuText ), "\w1. Buy every round shopmenu1 item^n" );
add( MenuText, charsmax( MenuText ), "\w2. Buy every round shopmenu2 item^n" );
add( MenuText, charsmax( MenuText ), "\w3. Stop to buy items^n" );
add( MenuText, charsmax( MenuText ), "^n\w0. Exit^n" );

// Add the keys
KEYS = (1<<9) | (1<<0) | (1<<1)| (1<<2);

// Show the menu
show_menu( id, KEYS, MenuText, 25, "BotMenu" );

return;
}

// Handle from the menu
public _HandleBotMenu( id, key )
{
if ( !is_user_connected( id ) )
{
return;
}

switch ( key )
{
case 0: ITEM_ShowShopmenu( id, 0 );
case 1: ITEM_ShowShopmenu( id, 1 );
case 2:
{
// Reset the data
p_data[id][PDATA_ITEM1] = -1;
p_data[id][PDATA_ITEM2] = -1;
}
}

return;
}

// Show the shopmenu
public ITEM_ShowShopmenu( id, page )
{
// The header
new MenuText[512] = "", KEYS = (1<<9);

if ( page == 0 )
{
copy ( MenuText, charsmax( MenuText ), "\yShopmenu 1^n^n" );
}

else if ( page == 1 )
{
copy ( MenuText, charsmax( MenuText ), "\yShopmenu 2^n^n" );
}

// Save the side
p_data[id][PDATA_ITEMSIDE] = page;

// Calculate the right page
page *= MAX_PAGE_ITEMS;

// Loop through all items
for ( new i = page; i < MAX_SHOPMENU_ITEMS; ++i )
{
// Add every item to the menutext
formatex( MenuText, charsmax( MenuText ), "%s\w%d. %s^n", MenuText, ( i+1 - page ), ShopmenuLong_Names[i] );

// Add every keypoint
KEYS |= (1<<(i-page));

// We're at the maximum. Go out of the loop
if ( ( i + 1) == MAX_PAGE_ITEMS )
{
break;
}
}

// Add the exit menupoint
add( MenuText, charsmax( MenuText ), "^n\w0. Exit^n" );

// Show the player the menu
show_menu ( id, KEYS, MenuText, 25, "Shopmenu12" );

return;
}

// Here we handle the pressed key from the shopmenu
public _ITEM_HandleShopMenu( id, key )
{
if ( !is_user_connected( id ) )
{
return;
}

// The player press the exit button
if ( key == 9 )
{
return;
}

// Calculate the pressed key with side
new MenuEntry = ( p_data[id][PDATA_ITEMSIDE] * MAX_PAGE_ITEMS ) + key;

// Save the id for the next round
if ( p_data[id][PDATA_ITEMSIDE] == 0 )
{
p_data[id][PDATA_ITEM1] = MenuEntry;
}

else if ( p_data[id][PDATA_ITEMSIDE] == 1 )
{
p_data[id][PDATA_ITEM2] = MenuEntry;
}

// tell him some shit ;P
client_print( id, print_chat, "You will recieve in the next round the item %s.", ShopmenuLong_Names[MenuEntry] );

return;
}

// Okay, we have to buy an item
ITEM_Buy( id, iItem )
{
// Call the function from wc3ft
if ( callfunc_begin ( "ITEM_Buy", "war3ft.amxx" ) == 1 )
{
callfunc_push_int( id );
callfunc_push_int( iItem );
callfunc_end();
}

// or uwc3ng
else if ( callfunc_begin ( "ITEM_Buy", "uwc3ng.amxx" ) == 1 )
{
callfunc_push_int( id );
callfunc_push_int( iItem );
callfunc_end();
}

// wth, found no mod
else
{
log_amx( "ERROR: Can't find uwc3ng.amxx or/and war3ft.amxx" );
}

return;
}

// Check if the player said one of the keywords to open the bot menu
public HandleSay( id )
{
// Get the complete text from the chat
static szArg[32];
read_args( szArg, charsmax( szArg ) );

// Convert the szArg to lowercase and without quotes
strtolower( szArg );
remove_quotes( szArg );

// The player said waritembot, wib, warcraftitembot, itembot
if ( equal( szArg, "waritembot" ) || equal( szArg, "wib" ) || equal( szArg, "warcraftitembot" ) || equal( szArg, "itembot" ) )
{
MENU_ItemBot( id );
}

return PLUGIN_CONTINUE;
}