public WC3_Damage( iVictim, iAttacker, iDamage, iWeapon, iBodyPart )
{

   // We have an invalid attacker/victim, that sucks...
   if ( iAttacker == 0 || iVictim == 0 )
   {
    return;
   }
     
   // User is not alive, why damage them more?
   if ( !is_user_alive( iVictim ) )
   {
    return;
   }

   // Don't damage if we shouldn't!
   if ( p_data_b[iVictim][PB_NO_DAMAGE] )
   {
    return;
   }

   // Warden's Hardened Skin
   iDamage = WA_HardenedSkin( iVictim, iDamage );

   if ( iBodyPart == -1 )
   {
    iBodyPart = random_num( 1, 7 );
   }

   // Modify the amount of damage done based on the user's armor
   if ( g_MOD == GAME_CSTRIKE || g_MOD == GAME_CZERO )
   {
    new Float:fNewDamage    = float( iDamage ) * ARMOR_RATIO;
    new Float:fArmorLost    = ( float( iDamage ) - fNewDamage ) * ARMOR_BONUS;
    new Float:fCurrentArmor    = float( get_user_armor( iVictim ) );

    // Does this use more armor than we have?
    if ( fArmorLost > fCurrentArmor )
    {
     fArmorLost = fCurrentArmor;
     fArmorLost *= ( 1 / ARMOR_BONUS );

     fNewDamage = float( iDamage ) - fArmorLost;

     set_user_armor( iVictim, 0 );
    }
    else
    {
     new iNewArmor = floatround( fCurrentArmor - ( 3.0 * fArmorLost ) );

     set_user_armor( iVictim, iNewArmor );
    }

    iDamage = floatround( fNewDamage );
   }

   new iHeadshot = 0;

   if ( g_MOD == GAME_CSTRIKE || g_MOD == GAME_CZERO )
   {
    if ( iBodyPart == 1 )
    {
     iHeadshot = 1;
    }
   }

   // Psychostats Statistics is turned on!
   if ( get_pcvar_num( CVAR_wc3_psychostats ) )
   {
    if ( CSW_WAR3_MIN <= iWeapon <= CSW_WAR3_MAX )
    {
     new iSkillWeapon = iWeapon - CSW_WAR3_MIN;
       
     // Make the "generic" the stomach
     if ( iBodyPart == -1 )
     {
      iBodyPart = HIT_STOMACH;
     }
      
     if ( iBodyPart == HIT_HEAD )
     {
      iStatsHead[iAttacker][iSkillWeapon]++;
     }
     else if ( iBodyPart == HIT_CHEST )
     {
      iStatsChest[iAttacker][iSkillWeapon]++;
     }
     else if ( iBodyPart == HIT_STOMACH )
     {
      iStatsStomach[iAttacker][iSkillWeapon]++;
     }
     else if ( iBodyPart == HIT_LEFTARM )
     {
      iStatsLeftArm[iAttacker][iSkillWeapon]++;
     }
     else if ( iBodyPart == HIT_RIGHTARM )
     {
      iStatsRightArm[iAttacker][iSkillWeapon]++;
     }
     else if ( iBodyPart == HIT_LEFTLEG )
     {
      iStatsLeftLeg[iAttacker][iSkillWeapon]++;
     }
     else if ( iBodyPart == HIT_RIGHTLEG )
     {
      iStatsRightLeg[iAttacker][iSkillWeapon]++;
     }

     iStatsHits[iAttacker][iSkillWeapon]++;
     iStatsShots[iAttacker][iSkillWeapon]++;
     iStatsDamage[iAttacker][iSkillWeapon] += iDamage;
    }
   }

   // Magical damage should go toward kill assist
   g_iDamageDealt[iAttacker][iVictim] += iDamage;

   new iHealth = get_user_health( iVictim );
     
   // User has been killed
   if ( iHealth - iDamage <= 0 )
   {
    WC3_Kill( iVictim, iAttacker, iWeapon, iHeadshot );
   }

   // Just do the damage
   else
   {
    set_user_health( iVictim, iHealth - iDamage );
   }

   return;
}